$ !!! VERIFY = F$VERIFY("NO")
$!
$! HELPTEX creates a HELP file from the .TEX command descriptions
$!    P1 is the .TEX file name (no extension)
$!    P2 is "AGAIN" iff HELPTEX does not need to be run
$!    P8 is the directory
$!
$ IF P8 .NES. "" THEN SET DEFAULT 'P8'
$!
$ BASEFILE = P1
$ BASEFILE = BASEFILE - ".TEX"
$!
$ IF F$SEARCH("''BASEFILE'.TEX") .NES. "" THEN GOTO ENDIF_FILE_OK
$    WRITE SYS$OUTPUT "''BASEFILE'.TEX does not exist"
$    GOTO END
$ ENDIF_FILE_OK:
$!
$ MEMTEXT :== @XACCESS$ROOT:[INSTALL]CONVERT -
                           XACCESS$ROOT:[INSTALL]MEMTEXT.EXE """MEM/TEXT"""
$ IF P2 .EQS. "AGAIN" THEN GOTO ENDIF_HELP
$ ASSIGN/USER 'BASEFILE'.TEX INFILE
$ ASSIGN/USER 'BASEFILE'.HELPRNO CMDFILE
$ ASSIGN/USER 'BASEFILE'.HELPSUM SUMFILE
$ RUN texexe:HELPTEX
$ PURGE 'BASEFILE'.HELPSUM
$ PURGE 'BASEFILE'.HELPRNO
$ ENDIF_HELP:
$!
$ RUNOFF 'BASEFILE'.HELPRNO /OUTPUT='BASEFILE.HELPMEM
$ MEMTEXT 'BASEFILE'.HELPMEM 'BASEFILE'.HELPMEM
$!
$ COPY 'BASEFILE'.HELPSUM, 'BASEFILE'.HELPMEM 'BASEFILE'.HELP
$ PURGE 'BASEFILE'.HELP
$ DELETE 'BASEFILE'.HELPMEM;*
$!
$ END:
$ !!! IF VERIFY THEN SET VERIFY