You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
292 lines
8.3 KiB
292 lines
8.3 KiB
2 years ago
|
*> \brief <b> CHBEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices</b>
|
||
|
|
*
|
||
|
|
* =========== DOCUMENTATION ===========
|
||
|
|
*
|
||
|
|
* Online html documentation available at
|
||
|
|
* http://www.netlib.org/lapack/explore-html/
|
||
|
|
*
|
||
|
|
*> \htmlonly
|
||
|
|
*> Download CHBEV + dependencies
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/chbev.f">
|
||
|
|
*> [TGZ]</a>
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/chbev.f">
|
||
|
|
*> [ZIP]</a>
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/chbev.f">
|
||
|
|
*> [TXT]</a>
|
||
|
|
*> \endhtmlonly
|
||
|
|
*
|
||
|
|
* Definition:
|
||
|
|
* ===========
|
||
|
|
*
|
||
|
|
* SUBROUTINE CHBEV( JOBZ, UPLO, N, KD, AB, LDAB, W, Z, LDZ, WORK,
|
||
|
|
* RWORK, INFO )
|
||
|
|
*
|
||
|
|
* .. Scalar Arguments ..
|
||
|
|
* CHARACTER JOBZ, UPLO
|
||
|
|
* INTEGER INFO, KD, LDAB, LDZ, N
|
||
|
|
* ..
|
||
|
|
* .. Array Arguments ..
|
||
|
|
* REAL RWORK( * ), W( * )
|
||
|
|
* COMPLEX AB( LDAB, * ), WORK( * ), Z( LDZ, * )
|
||
|
|
* ..
|
||
|
|
*
|
||
|
|
*
|
||
|
|
*> \par Purpose:
|
||
|
|
* =============
|
||
|
|
*>
|
||
|
|
*> \verbatim
|
||
|
|
*>
|
||
|
|
*> CHBEV computes all the eigenvalues and, optionally, eigenvectors of
|
||
|
|
*> a complex Hermitian band matrix A.
|
||
|
|
*> \endverbatim
|
||
|
|
*
|
||
|
|
* Arguments:
|
||
|
|
* ==========
|
||
|
|
*
|
||
|
|
*> \param[in] JOBZ
|
||
|
|
*> \verbatim
|
||
|
|
*> JOBZ is CHARACTER*1
|
||
|
|
*> = 'N': Compute eigenvalues only;
|
||
|
|
*> = 'V': Compute eigenvalues and eigenvectors.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] UPLO
|
||
|
|
*> \verbatim
|
||
|
|
*> UPLO is CHARACTER*1
|
||
|
|
*> = 'U': Upper triangle of A is stored;
|
||
|
|
*> = 'L': Lower triangle of A is stored.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] N
|
||
|
|
*> \verbatim
|
||
|
|
*> N is INTEGER
|
||
|
|
*> The order of the matrix A. N >= 0.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] KD
|
||
|
|
*> \verbatim
|
||
|
|
*> KD is INTEGER
|
||
|
|
*> The number of superdiagonals of the matrix A if UPLO = 'U',
|
||
|
|
*> or the number of subdiagonals if UPLO = 'L'. KD >= 0.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in,out] AB
|
||
|
|
*> \verbatim
|
||
|
|
*> AB is COMPLEX array, dimension (LDAB, N)
|
||
|
|
*> On entry, the upper or lower triangle of the Hermitian band
|
||
|
|
*> matrix A, stored in the first KD+1 rows of the array. The
|
||
|
|
*> j-th column of A is stored in the j-th column of the array AB
|
||
|
|
*> as follows:
|
||
|
|
*> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
|
||
|
|
*> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
|
||
|
|
*>
|
||
|
|
*> On exit, AB is overwritten by values generated during the
|
||
|
|
*> reduction to tridiagonal form. If UPLO = 'U', the first
|
||
|
|
*> superdiagonal and the diagonal of the tridiagonal matrix T
|
||
|
|
*> are returned in rows KD and KD+1 of AB, and if UPLO = 'L',
|
||
|
|
*> the diagonal and first subdiagonal of T are returned in the
|
||
|
|
*> first two rows of AB.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] LDAB
|
||
|
|
*> \verbatim
|
||
|
|
*> LDAB is INTEGER
|
||
|
|
*> The leading dimension of the array AB. LDAB >= KD + 1.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] W
|
||
|
|
*> \verbatim
|
||
|
|
*> W is REAL array, dimension (N)
|
||
|
|
*> If INFO = 0, the eigenvalues in ascending order.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] Z
|
||
|
|
*> \verbatim
|
||
|
|
*> Z is COMPLEX array, dimension (LDZ, N)
|
||
|
|
*> If JOBZ = 'V', then if INFO = 0, Z contains the orthonormal
|
||
|
|
*> eigenvectors of the matrix A, with the i-th column of Z
|
||
|
|
*> holding the eigenvector associated with W(i).
|
||
|
|
*> If JOBZ = 'N', then Z is not referenced.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] LDZ
|
||
|
|
*> \verbatim
|
||
|
|
*> LDZ is INTEGER
|
||
|
|
*> The leading dimension of the array Z. LDZ >= 1, and if
|
||
|
|
*> JOBZ = 'V', LDZ >= max(1,N).
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] WORK
|
||
|
|
*> \verbatim
|
||
|
|
*> WORK is COMPLEX array, dimension (N)
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] RWORK
|
||
|
|
*> \verbatim
|
||
|
|
*> RWORK is REAL array, dimension (max(1,3*N-2))
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] INFO
|
||
|
|
*> \verbatim
|
||
|
|
*> INFO is INTEGER
|
||
|
|
*> = 0: successful exit.
|
||
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value.
|
||
|
|
*> > 0: if INFO = i, the algorithm failed to converge; i
|
||
|
|
*> off-diagonal elements of an intermediate tridiagonal
|
||
|
|
*> form did not converge to zero.
|
||
|
|
*> \endverbatim
|
||
|
|
*
|
||
|
|
* Authors:
|
||
|
|
* ========
|
||
|
|
*
|
||
|
|
*> \author Univ. of Tennessee
|
||
|
|
*> \author Univ. of California Berkeley
|
||
|
|
*> \author Univ. of Colorado Denver
|
||
|
|
*> \author NAG Ltd.
|
||
|
|
*
|
||
|
|
*> \ingroup complexOTHEReigen
|
||
|
|
*
|
||
|
|
* =====================================================================
|
||
|
|
SUBROUTINE CHBEV( JOBZ, UPLO, N, KD, AB, LDAB, W, Z, LDZ, WORK,
|
||
|
|
$ RWORK, INFO )
|
||
|
|
*
|
||
|
|
* -- LAPACK driver routine --
|
||
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||
|
|
*
|
||
|
|
* .. Scalar Arguments ..
|
||
|
|
CHARACTER JOBZ, UPLO
|
||
|
|
INTEGER INFO, KD, LDAB, LDZ, N
|
||
|
|
* ..
|
||
|
|
* .. Array Arguments ..
|
||
|
|
REAL RWORK( * ), W( * )
|
||
|
|
COMPLEX AB( LDAB, * ), WORK( * ), Z( LDZ, * )
|
||
|
|
* ..
|
||
|
|
*
|
||
|
|
* =====================================================================
|
||
|
|
*
|
||
|
|
* .. Parameters ..
|
||
|
|
REAL ZERO, ONE
|
||
|
|
PARAMETER ( ZERO = 0.0E0, ONE = 1.0E0 )
|
||
|
|
* ..
|
||
|
|
* .. Local Scalars ..
|
||
|
|
LOGICAL LOWER, WANTZ
|
||
|
|
INTEGER IINFO, IMAX, INDE, INDRWK, ISCALE
|
||
|
|
REAL ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN, SIGMA,
|
||
|
|
$ SMLNUM
|
||
|
|
* ..
|
||
|
|
* .. External Functions ..
|
||
|
|
LOGICAL LSAME
|
||
|
|
REAL CLANHB, SLAMCH
|
||
|
|
EXTERNAL LSAME, CLANHB, SLAMCH
|
||
|
|
* ..
|
||
|
|
* .. External Subroutines ..
|
||
|
|
EXTERNAL CHBTRD, CLASCL, CSTEQR, SSCAL, SSTERF, XERBLA
|
||
|
|
* ..
|
||
|
|
* .. Intrinsic Functions ..
|
||
|
|
INTRINSIC SQRT
|
||
|
|
* ..
|
||
|
|
* .. Executable Statements ..
|
||
|
|
*
|
||
|
|
* Test the input parameters.
|
||
|
|
*
|
||
|
|
WANTZ = LSAME( JOBZ, 'V' )
|
||
|
|
LOWER = LSAME( UPLO, 'L' )
|
||
|
|
*
|
||
|
|
INFO = 0
|
||
|
|
IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
|
||
|
|
INFO = -1
|
||
|
|
ELSE IF( .NOT.( LOWER .OR. LSAME( UPLO, 'U' ) ) ) THEN
|
||
|
|
INFO = -2
|
||
|
|
ELSE IF( N.LT.0 ) THEN
|
||
|
|
INFO = -3
|
||
|
|
ELSE IF( KD.LT.0 ) THEN
|
||
|
|
INFO = -4
|
||
|
|
ELSE IF( LDAB.LT.KD+1 ) THEN
|
||
|
|
INFO = -6
|
||
|
|
ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
|
||
|
|
INFO = -9
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
IF( INFO.NE.0 ) THEN
|
||
|
|
CALL XERBLA( 'CHBEV ', -INFO )
|
||
|
|
RETURN
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* Quick return if possible
|
||
|
|
*
|
||
|
|
IF( N.EQ.0 )
|
||
|
|
$ RETURN
|
||
|
|
*
|
||
|
|
IF( N.EQ.1 ) THEN
|
||
|
|
IF( LOWER ) THEN
|
||
|
|
W( 1 ) = REAL( AB( 1, 1 ) )
|
||
|
|
ELSE
|
||
|
|
W( 1 ) = REAL( AB( KD+1, 1 ) )
|
||
|
|
END IF
|
||
|
|
IF( WANTZ )
|
||
|
|
$ Z( 1, 1 ) = ONE
|
||
|
|
RETURN
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* Get machine constants.
|
||
|
|
*
|
||
|
|
SAFMIN = SLAMCH( 'Safe minimum' )
|
||
|
|
EPS = SLAMCH( 'Precision' )
|
||
|
|
SMLNUM = SAFMIN / EPS
|
||
|
|
BIGNUM = ONE / SMLNUM
|
||
|
|
RMIN = SQRT( SMLNUM )
|
||
|
|
RMAX = SQRT( BIGNUM )
|
||
|
|
*
|
||
|
|
* Scale matrix to allowable range, if necessary.
|
||
|
|
*
|
||
|
|
ANRM = CLANHB( 'M', UPLO, N, KD, AB, LDAB, RWORK )
|
||
|
|
ISCALE = 0
|
||
|
|
IF( ANRM.GT.ZERO .AND. ANRM.LT.RMIN ) THEN
|
||
|
|
ISCALE = 1
|
||
|
|
SIGMA = RMIN / ANRM
|
||
|
|
ELSE IF( ANRM.GT.RMAX ) THEN
|
||
|
|
ISCALE = 1
|
||
|
|
SIGMA = RMAX / ANRM
|
||
|
|
END IF
|
||
|
|
IF( ISCALE.EQ.1 ) THEN
|
||
|
|
IF( LOWER ) THEN
|
||
|
|
CALL CLASCL( 'B', KD, KD, ONE, SIGMA, N, N, AB, LDAB, INFO )
|
||
|
|
ELSE
|
||
|
|
CALL CLASCL( 'Q', KD, KD, ONE, SIGMA, N, N, AB, LDAB, INFO )
|
||
|
|
END IF
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* Call CHBTRD to reduce Hermitian band matrix to tridiagonal form.
|
||
|
|
*
|
||
|
|
INDE = 1
|
||
|
|
CALL CHBTRD( JOBZ, UPLO, N, KD, AB, LDAB, W, RWORK( INDE ), Z,
|
||
|
|
$ LDZ, WORK, IINFO )
|
||
|
|
*
|
||
|
|
* For eigenvalues only, call SSTERF. For eigenvectors, call CSTEQR.
|
||
|
|
*
|
||
|
|
IF( .NOT.WANTZ ) THEN
|
||
|
|
CALL SSTERF( N, W, RWORK( INDE ), INFO )
|
||
|
|
ELSE
|
||
|
|
INDRWK = INDE + N
|
||
|
|
CALL CSTEQR( JOBZ, N, W, RWORK( INDE ), Z, LDZ,
|
||
|
|
$ RWORK( INDRWK ), INFO )
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* If matrix was scaled, then rescale eigenvalues appropriately.
|
||
|
|
*
|
||
|
|
IF( ISCALE.EQ.1 ) THEN
|
||
|
|
IF( INFO.EQ.0 ) THEN
|
||
|
|
IMAX = N
|
||
|
|
ELSE
|
||
|
|
IMAX = INFO - 1
|
||
|
|
END IF
|
||
|
|
CALL SSCAL( IMAX, ONE / SIGMA, W, 1 )
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
RETURN
|
||
|
|
*
|
||
|
|
* End of CHBEV
|
||
|
|
*
|
||
|
|
END
|