You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
253 lines
6.9 KiB
253 lines
6.9 KiB
2 years ago
|
*> \brief \b ZPPCON
|
||
|
|
*
|
||
|
|
* =========== DOCUMENTATION ===========
|
||
|
|
*
|
||
|
|
* Online html documentation available at
|
||
|
|
* http://www.netlib.org/lapack/explore-html/
|
||
|
|
*
|
||
|
|
*> \htmlonly
|
||
|
|
*> Download ZPPCON + dependencies
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zppcon.f">
|
||
|
|
*> [TGZ]</a>
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zppcon.f">
|
||
|
|
*> [ZIP]</a>
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zppcon.f">
|
||
|
|
*> [TXT]</a>
|
||
|
|
*> \endhtmlonly
|
||
|
|
*
|
||
|
|
* Definition:
|
||
|
|
* ===========
|
||
|
|
*
|
||
|
|
* SUBROUTINE ZPPCON( UPLO, N, AP, ANORM, RCOND, WORK, RWORK, INFO )
|
||
|
|
*
|
||
|
|
* .. Scalar Arguments ..
|
||
|
|
* CHARACTER UPLO
|
||
|
|
* INTEGER INFO, N
|
||
|
|
* DOUBLE PRECISION ANORM, RCOND
|
||
|
|
* ..
|
||
|
|
* .. Array Arguments ..
|
||
|
|
* DOUBLE PRECISION RWORK( * )
|
||
|
|
* COMPLEX*16 AP( * ), WORK( * )
|
||
|
|
* ..
|
||
|
|
*
|
||
|
|
*
|
||
|
|
*> \par Purpose:
|
||
|
|
* =============
|
||
|
|
*>
|
||
|
|
*> \verbatim
|
||
|
|
*>
|
||
|
|
*> ZPPCON estimates the reciprocal of the condition number (in the
|
||
|
|
*> 1-norm) of a complex Hermitian positive definite packed matrix using
|
||
|
|
*> the Cholesky factorization A = U**H*U or A = L*L**H computed by
|
||
|
|
*> ZPPTRF.
|
||
|
|
*>
|
||
|
|
*> An estimate is obtained for norm(inv(A)), and the reciprocal of the
|
||
|
|
*> condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
|
||
|
|
*> \endverbatim
|
||
|
|
*
|
||
|
|
* Arguments:
|
||
|
|
* ==========
|
||
|
|
*
|
||
|
|
*> \param[in] UPLO
|
||
|
|
*> \verbatim
|
||
|
|
*> UPLO is CHARACTER*1
|
||
|
|
*> = 'U': Upper triangle of A is stored;
|
||
|
|
*> = 'L': Lower triangle of A is stored.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] N
|
||
|
|
*> \verbatim
|
||
|
|
*> N is INTEGER
|
||
|
|
*> The order of the matrix A. N >= 0.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] AP
|
||
|
|
*> \verbatim
|
||
|
|
*> AP is COMPLEX*16 array, dimension (N*(N+1)/2)
|
||
|
|
*> The triangular factor U or L from the Cholesky factorization
|
||
|
|
*> A = U**H*U or A = L*L**H, packed columnwise in a linear
|
||
|
|
*> array. The j-th column of U or L is stored in the array AP
|
||
|
|
*> as follows:
|
||
|
|
*> if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j;
|
||
|
|
*> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] ANORM
|
||
|
|
*> \verbatim
|
||
|
|
*> ANORM is DOUBLE PRECISION
|
||
|
|
*> The 1-norm (or infinity-norm) of the Hermitian matrix A.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] RCOND
|
||
|
|
*> \verbatim
|
||
|
|
*> RCOND is DOUBLE PRECISION
|
||
|
|
*> The reciprocal of the condition number of the matrix A,
|
||
|
|
*> computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
|
||
|
|
*> estimate of the 1-norm of inv(A) computed in this routine.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] WORK
|
||
|
|
*> \verbatim
|
||
|
|
*> WORK is COMPLEX*16 array, dimension (2*N)
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] RWORK
|
||
|
|
*> \verbatim
|
||
|
|
*> RWORK is DOUBLE PRECISION array, dimension (N)
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] INFO
|
||
|
|
*> \verbatim
|
||
|
|
*> INFO is INTEGER
|
||
|
|
*> = 0: successful exit
|
||
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
||
|
|
*> \endverbatim
|
||
|
|
*
|
||
|
|
* Authors:
|
||
|
|
* ========
|
||
|
|
*
|
||
|
|
*> \author Univ. of Tennessee
|
||
|
|
*> \author Univ. of California Berkeley
|
||
|
|
*> \author Univ. of Colorado Denver
|
||
|
|
*> \author NAG Ltd.
|
||
|
|
*
|
||
|
|
*> \ingroup complex16OTHERcomputational
|
||
|
|
*
|
||
|
|
* =====================================================================
|
||
|
|
SUBROUTINE ZPPCON( UPLO, N, AP, ANORM, RCOND, WORK, RWORK, INFO )
|
||
|
|
*
|
||
|
|
* -- LAPACK computational routine --
|
||
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||
|
|
*
|
||
|
|
* .. Scalar Arguments ..
|
||
|
|
CHARACTER UPLO
|
||
|
|
INTEGER INFO, N
|
||
|
|
DOUBLE PRECISION ANORM, RCOND
|
||
|
|
* ..
|
||
|
|
* .. Array Arguments ..
|
||
|
|
DOUBLE PRECISION RWORK( * )
|
||
|
|
COMPLEX*16 AP( * ), WORK( * )
|
||
|
|
* ..
|
||
|
|
*
|
||
|
|
* =====================================================================
|
||
|
|
*
|
||
|
|
* .. Parameters ..
|
||
|
|
DOUBLE PRECISION ONE, ZERO
|
||
|
|
PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
|
||
|
|
* ..
|
||
|
|
* .. Local Scalars ..
|
||
|
|
LOGICAL UPPER
|
||
|
|
CHARACTER NORMIN
|
||
|
|
INTEGER IX, KASE
|
||
|
|
DOUBLE PRECISION AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
|
||
|
|
COMPLEX*16 ZDUM
|
||
|
|
* ..
|
||
|
|
* .. Local Arrays ..
|
||
|
|
INTEGER ISAVE( 3 )
|
||
|
|
* ..
|
||
|
|
* .. External Functions ..
|
||
|
|
LOGICAL LSAME
|
||
|
|
INTEGER IZAMAX
|
||
|
|
DOUBLE PRECISION DLAMCH
|
||
|
|
EXTERNAL LSAME, IZAMAX, DLAMCH
|
||
|
|
* ..
|
||
|
|
* .. External Subroutines ..
|
||
|
|
EXTERNAL XERBLA, ZDRSCL, ZLACN2, ZLATPS
|
||
|
|
* ..
|
||
|
|
* .. Intrinsic Functions ..
|
||
|
|
INTRINSIC ABS, DBLE, DIMAG
|
||
|
|
* ..
|
||
|
|
* .. Statement Functions ..
|
||
|
|
DOUBLE PRECISION CABS1
|
||
|
|
* ..
|
||
|
|
* .. Statement Function definitions ..
|
||
|
|
CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
|
||
|
|
* ..
|
||
|
|
* .. Executable Statements ..
|
||
|
|
*
|
||
|
|
* Test the input parameters.
|
||
|
|
*
|
||
|
|
INFO = 0
|
||
|
|
UPPER = LSAME( UPLO, 'U' )
|
||
|
|
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
||
|
|
INFO = -1
|
||
|
|
ELSE IF( N.LT.0 ) THEN
|
||
|
|
INFO = -2
|
||
|
|
ELSE IF( ANORM.LT.ZERO ) THEN
|
||
|
|
INFO = -4
|
||
|
|
END IF
|
||
|
|
IF( INFO.NE.0 ) THEN
|
||
|
|
CALL XERBLA( 'ZPPCON', -INFO )
|
||
|
|
RETURN
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* Quick return if possible
|
||
|
|
*
|
||
|
|
RCOND = ZERO
|
||
|
|
IF( N.EQ.0 ) THEN
|
||
|
|
RCOND = ONE
|
||
|
|
RETURN
|
||
|
|
ELSE IF( ANORM.EQ.ZERO ) THEN
|
||
|
|
RETURN
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
SMLNUM = DLAMCH( 'Safe minimum' )
|
||
|
|
*
|
||
|
|
* Estimate the 1-norm of the inverse.
|
||
|
|
*
|
||
|
|
KASE = 0
|
||
|
|
NORMIN = 'N'
|
||
|
|
10 CONTINUE
|
||
|
|
CALL ZLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
|
||
|
|
IF( KASE.NE.0 ) THEN
|
||
|
|
IF( UPPER ) THEN
|
||
|
|
*
|
||
|
|
* Multiply by inv(U**H).
|
||
|
|
*
|
||
|
|
CALL ZLATPS( 'Upper', 'Conjugate transpose', 'Non-unit',
|
||
|
|
$ NORMIN, N, AP, WORK, SCALEL, RWORK, INFO )
|
||
|
|
NORMIN = 'Y'
|
||
|
|
*
|
||
|
|
* Multiply by inv(U).
|
||
|
|
*
|
||
|
|
CALL ZLATPS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
|
||
|
|
$ AP, WORK, SCALEU, RWORK, INFO )
|
||
|
|
ELSE
|
||
|
|
*
|
||
|
|
* Multiply by inv(L).
|
||
|
|
*
|
||
|
|
CALL ZLATPS( 'Lower', 'No transpose', 'Non-unit', NORMIN, N,
|
||
|
|
$ AP, WORK, SCALEL, RWORK, INFO )
|
||
|
|
NORMIN = 'Y'
|
||
|
|
*
|
||
|
|
* Multiply by inv(L**H).
|
||
|
|
*
|
||
|
|
CALL ZLATPS( 'Lower', 'Conjugate transpose', 'Non-unit',
|
||
|
|
$ NORMIN, N, AP, WORK, SCALEU, RWORK, INFO )
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* Multiply by 1/SCALE if doing so will not cause overflow.
|
||
|
|
*
|
||
|
|
SCALE = SCALEL*SCALEU
|
||
|
|
IF( SCALE.NE.ONE ) THEN
|
||
|
|
IX = IZAMAX( N, WORK, 1 )
|
||
|
|
IF( SCALE.LT.CABS1( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
|
||
|
|
$ GO TO 20
|
||
|
|
CALL ZDRSCL( N, SCALE, WORK, 1 )
|
||
|
|
END IF
|
||
|
|
GO TO 10
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* Compute the estimate of the reciprocal condition number.
|
||
|
|
*
|
||
|
|
IF( AINVNM.NE.ZERO )
|
||
|
|
$ RCOND = ( ONE / AINVNM ) / ANORM
|
||
|
|
*
|
||
|
|
20 CONTINUE
|
||
|
|
RETURN
|
||
|
|
*
|
||
|
|
* End of ZPPCON
|
||
|
|
*
|
||
|
|
END
|