You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
231 lines
5.9 KiB
231 lines
5.9 KiB
2 years ago
|
*> \brief \b CUPGTR
|
||
|
|
*
|
||
|
|
* =========== DOCUMENTATION ===========
|
||
|
|
*
|
||
|
|
* Online html documentation available at
|
||
|
|
* http://www.netlib.org/lapack/explore-html/
|
||
|
|
*
|
||
|
|
*> \htmlonly
|
||
|
|
*> Download CUPGTR + dependencies
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cupgtr.f">
|
||
|
|
*> [TGZ]</a>
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cupgtr.f">
|
||
|
|
*> [ZIP]</a>
|
||
|
|
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cupgtr.f">
|
||
|
|
*> [TXT]</a>
|
||
|
|
*> \endhtmlonly
|
||
|
|
*
|
||
|
|
* Definition:
|
||
|
|
* ===========
|
||
|
|
*
|
||
|
|
* SUBROUTINE CUPGTR( UPLO, N, AP, TAU, Q, LDQ, WORK, INFO )
|
||
|
|
*
|
||
|
|
* .. Scalar Arguments ..
|
||
|
|
* CHARACTER UPLO
|
||
|
|
* INTEGER INFO, LDQ, N
|
||
|
|
* ..
|
||
|
|
* .. Array Arguments ..
|
||
|
|
* COMPLEX AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
|
||
|
|
* ..
|
||
|
|
*
|
||
|
|
*
|
||
|
|
*> \par Purpose:
|
||
|
|
* =============
|
||
|
|
*>
|
||
|
|
*> \verbatim
|
||
|
|
*>
|
||
|
|
*> CUPGTR generates a complex unitary matrix Q which is defined as the
|
||
|
|
*> product of n-1 elementary reflectors H(i) of order n, as returned by
|
||
|
|
*> CHPTRD using packed storage:
|
||
|
|
*>
|
||
|
|
*> if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),
|
||
|
|
*>
|
||
|
|
*> if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).
|
||
|
|
*> \endverbatim
|
||
|
|
*
|
||
|
|
* Arguments:
|
||
|
|
* ==========
|
||
|
|
*
|
||
|
|
*> \param[in] UPLO
|
||
|
|
*> \verbatim
|
||
|
|
*> UPLO is CHARACTER*1
|
||
|
|
*> = 'U': Upper triangular packed storage used in previous
|
||
|
|
*> call to CHPTRD;
|
||
|
|
*> = 'L': Lower triangular packed storage used in previous
|
||
|
|
*> call to CHPTRD.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] N
|
||
|
|
*> \verbatim
|
||
|
|
*> N is INTEGER
|
||
|
|
*> The order of the matrix Q. N >= 0.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] AP
|
||
|
|
*> \verbatim
|
||
|
|
*> AP is COMPLEX array, dimension (N*(N+1)/2)
|
||
|
|
*> The vectors which define the elementary reflectors, as
|
||
|
|
*> returned by CHPTRD.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] TAU
|
||
|
|
*> \verbatim
|
||
|
|
*> TAU is COMPLEX array, dimension (N-1)
|
||
|
|
*> TAU(i) must contain the scalar factor of the elementary
|
||
|
|
*> reflector H(i), as returned by CHPTRD.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] Q
|
||
|
|
*> \verbatim
|
||
|
|
*> Q is COMPLEX array, dimension (LDQ,N)
|
||
|
|
*> The N-by-N unitary matrix Q.
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[in] LDQ
|
||
|
|
*> \verbatim
|
||
|
|
*> LDQ is INTEGER
|
||
|
|
*> The leading dimension of the array Q. LDQ >= max(1,N).
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] WORK
|
||
|
|
*> \verbatim
|
||
|
|
*> WORK is COMPLEX array, dimension (N-1)
|
||
|
|
*> \endverbatim
|
||
|
|
*>
|
||
|
|
*> \param[out] INFO
|
||
|
|
*> \verbatim
|
||
|
|
*> INFO is INTEGER
|
||
|
|
*> = 0: successful exit
|
||
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
||
|
|
*> \endverbatim
|
||
|
|
*
|
||
|
|
* Authors:
|
||
|
|
* ========
|
||
|
|
*
|
||
|
|
*> \author Univ. of Tennessee
|
||
|
|
*> \author Univ. of California Berkeley
|
||
|
|
*> \author Univ. of Colorado Denver
|
||
|
|
*> \author NAG Ltd.
|
||
|
|
*
|
||
|
|
*> \ingroup complexOTHERcomputational
|
||
|
|
*
|
||
|
|
* =====================================================================
|
||
|
|
SUBROUTINE CUPGTR( UPLO, N, AP, TAU, Q, LDQ, WORK, INFO )
|
||
|
|
*
|
||
|
|
* -- LAPACK computational routine --
|
||
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||
|
|
*
|
||
|
|
* .. Scalar Arguments ..
|
||
|
|
CHARACTER UPLO
|
||
|
|
INTEGER INFO, LDQ, N
|
||
|
|
* ..
|
||
|
|
* .. Array Arguments ..
|
||
|
|
COMPLEX AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
|
||
|
|
* ..
|
||
|
|
*
|
||
|
|
* =====================================================================
|
||
|
|
*
|
||
|
|
* .. Parameters ..
|
||
|
|
COMPLEX CZERO, CONE
|
||
|
|
PARAMETER ( CZERO = ( 0.0E+0, 0.0E+0 ),
|
||
|
|
$ CONE = ( 1.0E+0, 0.0E+0 ) )
|
||
|
|
* ..
|
||
|
|
* .. Local Scalars ..
|
||
|
|
LOGICAL UPPER
|
||
|
|
INTEGER I, IINFO, IJ, J
|
||
|
|
* ..
|
||
|
|
* .. External Functions ..
|
||
|
|
LOGICAL LSAME
|
||
|
|
EXTERNAL LSAME
|
||
|
|
* ..
|
||
|
|
* .. External Subroutines ..
|
||
|
|
EXTERNAL CUNG2L, CUNG2R, XERBLA
|
||
|
|
* ..
|
||
|
|
* .. Intrinsic Functions ..
|
||
|
|
INTRINSIC MAX
|
||
|
|
* ..
|
||
|
|
* .. Executable Statements ..
|
||
|
|
*
|
||
|
|
* Test the input arguments
|
||
|
|
*
|
||
|
|
INFO = 0
|
||
|
|
UPPER = LSAME( UPLO, 'U' )
|
||
|
|
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
||
|
|
INFO = -1
|
||
|
|
ELSE IF( N.LT.0 ) THEN
|
||
|
|
INFO = -2
|
||
|
|
ELSE IF( LDQ.LT.MAX( 1, N ) ) THEN
|
||
|
|
INFO = -6
|
||
|
|
END IF
|
||
|
|
IF( INFO.NE.0 ) THEN
|
||
|
|
CALL XERBLA( 'CUPGTR', -INFO )
|
||
|
|
RETURN
|
||
|
|
END IF
|
||
|
|
*
|
||
|
|
* Quick return if possible
|
||
|
|
*
|
||
|
|
IF( N.EQ.0 )
|
||
|
|
$ RETURN
|
||
|
|
*
|
||
|
|
IF( UPPER ) THEN
|
||
|
|
*
|
||
|
|
* Q was determined by a call to CHPTRD with UPLO = 'U'
|
||
|
|
*
|
||
|
|
* Unpack the vectors which define the elementary reflectors and
|
||
|
|
* set the last row and column of Q equal to those of the unit
|
||
|
|
* matrix
|
||
|
|
*
|
||
|
|
IJ = 2
|
||
|
|
DO 20 J = 1, N - 1
|
||
|
|
DO 10 I = 1, J - 1
|
||
|
|
Q( I, J ) = AP( IJ )
|
||
|
|
IJ = IJ + 1
|
||
|
|
10 CONTINUE
|
||
|
|
IJ = IJ + 2
|
||
|
|
Q( N, J ) = CZERO
|
||
|
|
20 CONTINUE
|
||
|
|
DO 30 I = 1, N - 1
|
||
|
|
Q( I, N ) = CZERO
|
||
|
|
30 CONTINUE
|
||
|
|
Q( N, N ) = CONE
|
||
|
|
*
|
||
|
|
* Generate Q(1:n-1,1:n-1)
|
||
|
|
*
|
||
|
|
CALL CUNG2L( N-1, N-1, N-1, Q, LDQ, TAU, WORK, IINFO )
|
||
|
|
*
|
||
|
|
ELSE
|
||
|
|
*
|
||
|
|
* Q was determined by a call to CHPTRD with UPLO = 'L'.
|
||
|
|
*
|
||
|
|
* Unpack the vectors which define the elementary reflectors and
|
||
|
|
* set the first row and column of Q equal to those of the unit
|
||
|
|
* matrix
|
||
|
|
*
|
||
|
|
Q( 1, 1 ) = CONE
|
||
|
|
DO 40 I = 2, N
|
||
|
|
Q( I, 1 ) = CZERO
|
||
|
|
40 CONTINUE
|
||
|
|
IJ = 3
|
||
|
|
DO 60 J = 2, N
|
||
|
|
Q( 1, J ) = CZERO
|
||
|
|
DO 50 I = J + 1, N
|
||
|
|
Q( I, J ) = AP( IJ )
|
||
|
|
IJ = IJ + 1
|
||
|
|
50 CONTINUE
|
||
|
|
IJ = IJ + 2
|
||
|
|
60 CONTINUE
|
||
|
|
IF( N.GT.1 ) THEN
|
||
|
|
*
|
||
|
|
* Generate Q(2:n,2:n)
|
||
|
|
*
|
||
|
|
CALL CUNG2R( N-1, N-1, N-1, Q( 2, 2 ), LDQ, TAU, WORK,
|
||
|
|
$ IINFO )
|
||
|
|
END IF
|
||
|
|
END IF
|
||
|
|
RETURN
|
||
|
|
*
|
||
|
|
* End of CUPGTR
|
||
|
|
*
|
||
|
|
END
|